working on it

05/musl-final/src/setjmp/i386/longjmp.s

@@ -0,0 +1,22 @@
+.global _longjmp
+.global longjmp
+.type _longjmp,%function
+.type longjmp,%function
+_longjmp:
+longjmp:
+	movl  4(%esp),%edx
+	movl  8(%esp),%eax
+	testl    %eax,%eax
+	jnz .L0
+	incl     %eax
+.L0:
+	movl   (%edx),%ebx
+	movl  4(%edx),%esi
+	movl  8(%edx),%edi
+	movl 12(%edx),%ebp
+	movl 16(%edx),%ecx
+	movl     %ecx,%esp
+	movl 20(%edx),%ecx
+	jmp *%ecx
+.size _longjmp,.-_longjmp
+.size longjmp,.-longjmp

05/musl-final/src/setjmp/i386/setjmp.s

@@ -0,0 +1,23 @@
+.global __setjmp
+.global _setjmp
+.global setjmp
+.type __setjmp,%function
+.type _setjmp,%function
+.type setjmp,%function
+__setjmp:
+_setjmp:
+setjmp:
+	movl 4(%esp), %eax
+	movl    %ebx, (%eax)
+	movl    %esi, 4(%eax)
+	movl    %edi, 8(%eax)
+	movl    %ebp, 12(%eax)
+	leal 4(%esp), %ecx
+	movl    %ecx, 16(%eax)
+	movl  (%esp), %ecx
+	movl    %ecx, 20(%eax)
+	xorl    %eax, %eax
+	ret
+.size __setjmp,.-__setjmp
+.size _setjmp,.-_setjmp
+.size setjmp,.-setjmp

05/musl-final/src/setjmp/x86_64/longjmp.s

@@ -0,0 +1,24 @@
+/* Copyright 2011 Nicholas J. Kain, licensed GNU LGPL 2.1 or later */
+.global _longjmp
+.global longjmp
+.type _longjmp,%function
+.type longjmp,%function
+_longjmp:
+longjmp:
+	mov %rsi,%rax           /* val will be longjmp return */
+	test %rax,%rax
+	jnz .L0
+	inc %rax                /* if val==0, val=1 per longjmp semantics */
+.L0:
+	movq (%rdi),%rbx        /* rdi is the jmp_buf, restore regs from it */
+	movq 8(%rdi),%rbp
+	movq 16(%rdi),%r12
+	movq 24(%rdi),%r13
+	movq 32(%rdi),%r14
+	movq 40(%rdi),%r15
+	movq 48(%rdi),%rdx      /* this ends up being the stack pointer */
+	mov %rdx,%rsp
+	movq 56(%rdi),%rdx      /* this is the instruction pointer */
+	jmp *%rdx               /* goto saved address without altering rsp */
+.size _longjmp,.-_longjmp
+.size longjmp,.-longjmp

05/musl-final/src/setjmp/x86_64/setjmp.s

@@ -0,0 +1,25 @@
+/* Copyright 2011 Nicholas J. Kain, licensed GNU LGPL 2.1 or later */
+.global __setjmp
+.global _setjmp
+.global setjmp
+.type __setjmp,%function
+.type _setjmp,%function
+.type setjmp,%function
+__setjmp:
+_setjmp:
+setjmp:
+	mov %rbx,(%rdi)         /* rdi is jmp_buf, move registers onto it */
+	mov %rbp,8(%rdi)
+	mov %r12,16(%rdi)
+	mov %r13,24(%rdi)
+	mov %r14,32(%rdi)
+	mov %r15,40(%rdi)
+	leaq 8(%rsp),%rdx       /* this is our rsp WITHOUT current ret addr */
+	mov %rdx,48(%rdi)
+	movq (%rsp),%rdx        /* save return addr ptr for new rip */
+	mov %rdx,56(%rdi)
+	xor %rax,%rax           /* always return 0 */
+	ret
+.size __setjmp,.-__setjmp
+.size _setjmp,.-_setjmp
+.size setjmp,.-setjmp